***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jan 24, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BAS100AS A K 
.param
+vc1 = 1.334e-5
+rr1 = 1.258e-4
+vc2 = 5.808e-2
+tc1 = 1.313e-1
+tc2 = 4.816e-3
+tc3 = 8.384e-2
+tc4 = 3.882e-2
gdiode K A value={(vc1*v(K,A)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+rr1*exp(vc2*v(K,A)))*1e-6*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K diode
.model diode d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ibv = 0.5e-3   
+is = 1.068e-9
+n = 1.063
+rs = 2.764e-1
+ikf = 1.1e-2
+bv = 110 
***** capacitance parameter ***
+cjo = 4.733e-11
+m = 4.669e-1
+vj = 5.457e-1
+fc = 0.5  
***** temperature coefficient ***
+tnom = 25                     
+eg = 7.681e-1
+xti = 3 
+trs1 = -4.421e-3
+trs2 = -1.005e-5
+tikf = -1e-3
.ends BAS100AS
*$
